PivotTable, Slicer ve Chart nesneleriyle çalışmak

Giriş

Pivot(Özet) tablolarla çalışmaya başlamadan önce Excel tarafında konuya hakim olmak önemlidir. Buraya kadar geldiğinize göre konuyu bildiğinizi varsayıyorum ancak bilgilerinizi tazlemek isterseniz sizi şöyle alayım.

Baştan belirtmekte fayda var; Pivot tablo(bundan sonra PT diye anılacak) konusu VBA tarafında biraz alengirli bir hal alır, zira Excel önyüzde görmediğimiz bir nesneyle çalışmamız gerekmektedir. Bunun adı PivotCachedir. Onun dışında aslında recorder ile üreteceğiniz birkaç kodu elden geçirmekle kolaylıkla öğrenebileceğiniz bir konudur. O yüzden ben bu sayfada gereksiz yere recorderla elde edebileceğiniz detayları koymamaya karar verdim. Onun yerine refresh işlemleri, birkaç önemli işlem, birkaç event ve sonrasında da slicerlarla olan ilişkisini anlatmak istiyorum. Tabiki otomasyon projelerinizde data üretimi sonrasında kodun bir PT da üretmesi gerekiyorsa PT yaratmayı bilmeniz lazım ama dediğim gibi bunu recorderla çok rahat görebilirsiniz, gereksiz fazlalıkları atmak size kalıyor.

Size tavsiyem öncelikle birkaç işlemi(pivot oluşturma, filtre koyma, filtre kaldırma, repeat all items yapma v.s) recorder ile yapın ve kodu inceleyin. Yine de "ben recorderla uğraşamam" diyorsanız MSDN'den detay bilgi edinebilirsiniz. İngilizceniz yoksa ve pivot detaylarını yine de yazmamı isterseniz bu sayfanın altına yorum bırakın, uygun bir zamanda bunları da eklerim, ama dediğim gibi gerçekten burada anlatacaklarım dışında nerdeyse herşeyi recorderla kolaylıkla elde edebilirsiniz ve bunlarla ilgili olarak dikkat çekecek bir husus bulunmamaktadır.

Veri Seti

Üzerinde çalışacağımız data seti, Excel konularındaki örnek data setidir, buradan indirebilirsiniz.

Mesela aşağıda, bu dosyanın "calculatedlar" sayfasındaki dataya uyguladığımız PT'ın recorderla elde edilmiş kodu bulunuyor. Tabi bu kodu şu an çalıştırsanız sizde çalışmaz zira sayfa isimleri değişmiş olacak. Onun yerine kendiniz yeni bir recorder çalıştırıp görün derim.

                        
                                    Sub Macro1()
                                    '
                                    ' Macro1 Macro
                                    '
                                    '
                                        Sheets.Add
                                        ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _
                                            "calculatedlar!R1C1:R175C6", Version:=6).CreatePivotTable TableDestination _
                                            :="Sheet1!R3C1", TableName:="PivotTable1", DefaultVersion:=6
                                        Sheets("Sheet1").Select
                                        Cells(3, 1).Select
                                        With ActiveSheet.PivotTables("PivotTable1")
                                            .ColumnGrand = True
                                            .HasAutoFormat = True
                                            .DisplayErrorString = False
                                            .DisplayNullString = True
                                            .EnableDrilldown = True
                                            .ErrorString = ""
                                            .MergeLabels = False
                                            .NullString = ""
                                            .PageFieldOrder = 2
                                            .PageFieldWrapCount = 0
                                            .PreserveFormatting = True
                                            .RowGrand = True
                                            .SaveData = True
                                            .PrintTitles = False
                                            .RepeatItemsOnEachPrintedPage = True
                                            .TotalsAnnotation = False
                                            .CompactRowIndent = 1
                                            .InGridDropZones = False
                                            .DisplayFieldCaptions = True
                                            .DisplayMemberPropertyTooltips = False
                                            .DisplayContextTooltips = True
                                            .ShowDrillIndicators = True
                                            .PrintDrillIndicators = False
                                            .AllowMultipleFilters = False
                                            .SortUsingCustomLists = True
                                            .FieldListSortAscending = False
                                            .ShowValuesRow = False
                                            .CalculatedMembersInFilters = False
                                            .RowAxisLayout xlCompactRow
                                        End With
                                        With ActiveSheet.PivotTables("PivotTable1").PivotCache
                                            .RefreshOnFileOpen = False
                                            .MissingItemsLimit = xlMissingItemsDefault
                                        End With
                                        ActiveSheet.PivotTables("PivotTable1").RepeatAllLabels xlRepeatLabels
                                        With ActiveSheet.PivotTables("PivotTable1").PivotFields("KANAL")
                                            .Orientation = xlRowField
                                            .Position = 1
                                        End With
                                        With ActiveSheet.PivotTables("PivotTable1").PivotFields("URUN")
                                            .Orientation = xlColumnField
                                            .Position = 1
                                        End With
                                        ActiveSheet.PivotTables("PivotTable1").AddDataField ActiveSheet.PivotTables( _
                                            "PivotTable1").PivotFields("TUTAR"), "Sum of TUTAR", xlSum
                                    End Sub
                                                
                                            

Yukarıda da bahsettiğim gibi recorder kodunda gereksiz bir sürü kısım var, zira artık bildiğiniz üzere recorder bir nesneye ait tüm propertylere değer atıyor.

PivotCache nesnesi

Yukarıdaki koddan göreceğiniz üzere bir pivot table yaratılmadan önce PivotCache(Bundan sonra PC olarak anılacak) nesnesi yaratılıyor. PC, veri kaynağının bellekte özetlenmiş halidir . Her PT'ın arka planda dayandığı bir PC vardır. Neden böyle bir şeye ihtiyaç var diye sorabilirsiniz. PT'lar bence ve birçok kişi tarafından Excel'in en güçlü aracı olarak kabul edilir. Bunların gücü, birçok gruplama işini çok hızlı yapmasında yatıyor. İşte bu hız, bellekteki PC tarafından sağlanır, aksi halde her defasında veri kaynağına gitmek gerekseydi ki bu da hızın düşüşü anlamına gelecekti. İşte bu yüzden öncelikle PC yaratılır.

Excel 2007'den önce bir veri kaynağından üretilen her PT'ın ayrı bir PC'si olurdu, bu da bellek tüketimi için çok iyi olmazdı ve dosya boyutunu da gereksiz yere şişirirdi. Excel 2007 ile birlikte aynı kaynaktan üretilen PT'ların PC'si ortaklaştırıldı. Bununla beraber bazı durumlarda bunların PC'sini ayrıştırmak gerekebilir, bunu nasıl yapacağımızı aşağıda göreceğiz.

Rakamlarla örnek vermek gerekirse; 2007 öncesinde kaynak datanız 1 MB büyüklüğündeyse ve 3 PT yarattıysanız dosya boyutu 3 MB daha artıyordu. 2007 ve sonrasında sadece 1 MB artıyor. Bu 1 MB'dan da tasarruf etmek için "save source data" yapabilirsiniz.

Aşağıda benim üzerinde çalıştığım birkaç dosyanın boyutunu görebilirsiniz(Edit:Dosya adlarındaki baştaki "pivot"u görmezden gelin):

Daha detaylı analiz ettiğimizde;

• Boş bir dosya 9 KB
• Sadece kaynak datayı içerdiğinde 57 KB. Demekki datanın getirdiği net yük: 57-9=48 KB
• Bu dosyada tek bir PT yaratınca boyut 79'a çıkıyor. Demekki, cache + pivot sayfasındaki özet data=79-48=31 KB(Gerçi özet alanında hiç veri koymasam da boyut yine 79, demek özet veri ihmal edilebilir)
• 2. PT yaratınca boyut 79’dan 93’e çıkıyor. Bu da cache’den 14 KB. Bu da pivot alanı için 7 KB bir alan tanıyor demek.
• 3. PT yaratınca boyut 93'ten 107'ye çıkıyor. Yani son PT'ya 14 KB daha tanımış oluyorum. Bu da son PT'nın cache ile ilgili olarak 14 KB'lık bir alana sahip olduğu anlamına geliyor.
• Hepsi için toplamda 48+31+14+14=107

Yukarıda gördüğünüz üzere aslında data kaynağına gidip her seferinde veri almak yerine, bellekte bir PC tutarak, bunun üzerinden özetleme işlemlerini gerçekleştiriyor.

Sonuç olarak; Her PT için bir PC oluşturmak ve bunları eklemek gerekli. İşte bu yüzden kod içerisinde yukarıdaki gibi "PivotCaches.Create" ile PC yaratmak durumundayız.

Pivot Tabloların Oluşturulması

PT oluşturmak için yukarıda gördüğümüz kodu kullanabiliriz. Burada dikkat edilmesi gereken husus PivotCaches.Create metodu. Bunun dışında bazı propertiesler üzerinden de işlem yapmamız gerekebilir. Aşağıdaki gibi bir kod ile PT yaratılabilir.

                        
                                Sub PivotTableOlustur()
                                    Dim pc As PivotCache
                                    Dim pt As PivotTable
                                    Dim ws As Worksheet
                                    Dim wsData As Worksheet
                                    Set ws = Worksheets.Add
                                    Set wsData = Worksheets("calculatedlar")
                                    Set pc = ActiveWorkbook.PivotCaches.Create( _
                                        SourceType:=xlDatabase, _
                                        SourceData:=wsData.Range("A1:F175"))
                                    Set pt = pc.CreatePivotTable( _
                                        TableDestination:=ws.Range("A3"), _
                                        TableName:="PivotTable1")
                                End Sub
                                            
                                        

Yukarıdaki kodda dikkat edilmesi gereken nokta "SourceData" alanıdır. Burada yine belirtilen veri aralığına dikkat etmek önemlidir. Bu aralık dışında PT yaratmaya çalışırsanız hata alırsınız. O yüzden aralık kontrolü yapmak iyi bir yöntem olacaktır. Bu noktada birkaç tane error handling metodu kullanılabilir. Bunları aşağıda görmeye çalışacağız.

Aralık Kontrolü

Pivot tabloyu oluştururken belirli bir aralığın kontrolünü sağlamak gerekir. Bunun için aşağıdaki yöntem kullanılabilir:

                                                        
                                Sub PivotTableOlustur()
                                    On Error GoTo Hata
                                    Dim pc As PivotCache
                                    Dim pt As PivotTable
                                    Dim ws As Worksheet
                                    Dim wsData As Worksheet
                                    Dim aralik As Range
                                    Set ws = Worksheets.Add
                                    Set wsData = Worksheets("calculatedlar")
                                    Set aralik = wsData.Range("A1:F175")
                                    If Application.WorksheetFunction.CountA(aralik) = 0 Then
                                        MsgBox "Veri kaynağı boş. Lütfen kontrol ediniz."
                                        Exit Sub
                                    End If
                                    Set pc = ActiveWorkbook.PivotCaches.Create( _
                                        SourceType:=xlDatabase, _
                                        SourceData:=aralik)
                                    Set pt = pc.CreatePivotTable( _
                                        TableDestination:=ws.Range("A3"), _
                                        TableName:="PivotTable1")
                                    Exit Sub
                                Hata:
                                    MsgBox "Hata oluştu: " & Err.Description
                                End Sub
                                            
                                        

Yukarıdaki kodda veri aralığı kontrol ediliyor. Application.WorksheetFunction.CountA fonksiyonu ile aralıkta veri olup olmadığı kontrol ediliyor. Eğer aralık boşsa kullanıcıya bir mesaj veriliyor ve kod çalışmayı durduruyor. Eğer bir hata oluşursa, On Error ifadesi ile hata mesajı gösteriliyor.

Pivot Tabloların Yeniden Oluşturulması

Eğer tabloyu yeniden oluşturmak gerekirse, PT üzerinde PivotTable.ClearTable metodu ile tablo temizlenebilir. Daha sonra yukarıdaki gibi yeniden oluşturulabilir.

                        
                            Sub PivotTableTemizle()
                                Dim ws As Worksheet
                                Dim pt As PivotTable
                                Set ws = Worksheets("Sheet1")
                                Set pt = ws.PivotTables("PivotTable1")
                                pt.ClearTable
                            End Sub
                                        
                                    

Yukarıdaki kodda belirtilen tablo temizleniyor. Eğer tablo tamamen silinmek istenirse PivotTable.Delete metodu kullanılabilir. Bunu yaparken dikkat edilmesi gereken bir husus, tablo silindikten sonra o tabloya referans veren herhangi bir kod varsa, çalışmayacaktır.

PT'daki bir Field'da filtreli elemanları elde etme

Bir field'da seçili olan elemanları elde etmek VisibleItems özelliği ile oldukça kolaydır. Aşağıda, parametre olarak sayfa, PT adı ve field adını alan bir fonksiyonumuz ve bu fonksiyonu çağıran bir test prosedürümüz bulunuyor. Bu arada fonksiyonumuzun dönüş tipi PivotItems olup döngüsel olarak içinde dönerek elemanları yazdırıyoruz. (Dönüş tipini collection olarak da belirleyebilirdik, ancak bu sefer elemanları tek tek geçici bir Collection nesnesine atmak gerekirdi. Bu örneği Slicerdaki seçili elemanları getirme örneğinde yapacağız.)

                    
                                Function Pivotun1FieldındakileriGetir(ws As Worksheet, ptName As String, ptfield As String) As PivotItems
                                    'tek bir field için basit örnek
                                    Dim pt As PivotTable
                                    Dim pf As PivotField

                                    Set pt = ws.PivotTables(ptName)
                                    Set pf = pt.PivotFields(ptfield)
                                    Set Pivotun1FieldındakileriGetir = pf.VisibleItems
                                End Function
                                    Sub test_pivot_seçili_elemanlar()
                                        'Örnek olarak, Tarihsl Datanın Pivot ve Slcr sayfasındayken çalıştırabilirsiniz. Pivotta bikaç bölge filtreli olsun
                                        Dim kimlerseçili As PivotItems

                                        Set kimlerseçili = Pivotun1FieldındakileriGetir(ActiveSheet, "ptBolgekodUrun", "Bölge Kodu")
                                        For Each vi In kimlerseçili
                                            Debug.Print vi.Name
                                        Next vi
                                    End Sub
                                    
                                    

PT'daki birden fazla fieldda seçili olan elemanları elde etme

Bu sefer, hangi fieldda hangi değerlere filtre konmuş, bunları elde edeceğiz. Tabi şimdi işimiz biraz daha zor, o yüzden farklı bir bakış açısıyla yaklaşmak lazım. Aslında bu paragrafın ilk cümlesi bize bir dictionary'nin gerekliliğini gösteriyor: Hangi fieldda ne seçili, yani bildiğimiz Key ve Value ikilisi. O yüzden fonksiyonumuzun dönüş tipini bu sefer Dictionary olarak tanımlayacağız.

Tekil field örneğinden farklı olarak bu sefer Field isimlerini bir collection'a atayıp gönderiyoruz. Fonksiyonumuzdan gelen bilgileri yazdırırken de "birleştir" isimli yardımcı bir fonksiyon ile her fielddaki itemları yan yana birleştirip öyle yazdırıyoruz.

                    
                                Function PivotunÇokluFieldındakileriGetir(ws As Worksheet, ptName As String, ptfields As Collection) As Dictionary
                                    Dim pt As PivotTable
                                    Dim pf As PivotField
                                    Dim dict As New Dictionary

                                    Set pt = ws.PivotTables(ptName)
                                    For Each p In ptfields
                                        Set pf = pt.PivotFields(p)
                                        dict.Add p, pf.VisibleItems
                                    Next p

                                    Set PivotunÇokluFieldındakileriGetir = dict
                                End Function
                                    Sub test_pivot_seçili_elemanlar_çoklufield()
                                        'Örnek olarak, Tarihsl Datanın Pivot ve Slcr sayfasındayken çalıştırabilirsiniz. Pivotta bikaç bölge ve ürün filtreli olsun
                                        Dim mydict As Dictionary
                                        Dim alanlar As New Collection
                                        alanlar.Add "Bölge Kodu"
                                        alanlar.Add "Ürün"

                                        Set mydict = PivotunÇokluFieldındakileriGetir(ActiveSheet, "ptBolgekodUrun", alanlar)
                                        For Each k In mydict.Keys
                                            Debug.Print k, birleştir(mydict(k))
                                        Next k
                                    End Sub
                                    Function birleştir(pis As PivotItems)
                                        For Each pi In pis
                                            geçici = geçici & "-" & pi
                                        Next pi
                                        birleştir = Mid(geçici, 2)
                                    End Function
                                    
                                    

Aşağıdaki örnek üzerinden çalıştırdığımızda dönen sonuç da şöyle olmaktadır.

Bölge Kodu Başkent 1-Ege 2
                                Ürün ÜÜrün Ürün4-Ürün3-Ürün2

Bir fieldda filtre var mı kontrolü

Burada da AllItemsVisible şeklinde boolean tipli bir property ile sorgulamamızı yapabiliyoruz.

                                                    
                                Function pivot_field_filtrelimi(ws As Worksheet, ptName As String, ptfield As String) As Boolean
                                    pivot_field_filtrelimi = Not ws.PivotTables(ptName).PivotFields(ptfield).AllItemsVisible
                                End Function
                                    Sub test_pivot_field_filtrelimi()
                                        'data sayfasında çalıştırın
                                        Debug.Print pivot_field_filtrelimi(ActiveSheet, "PivotTable1", "Bölge")
                                        Debug.Print pivot_field_filtrelimi(ActiveSheet, "PivotTable1", "Şube Adı")
                                    End Sub
                                    
                                    

Bir fieldda 1 adet filtre kriteri uygulamak

Tek bir field üzerinde 1 adet filtre uygulamanın en pratik yolu PivotFilters nesnesini kullanmaktır. Syntaxı aşağıdaki örnekten görüldüğü üzere oldukça pratiktir. Type argümanının alacağı değerlerin intellisense ile çıkmasını isterseniz PivotFilters nesnesini en başta Dim ile tanımlayıp öyle ilerleyebilirsiniz. Aşağıdaki örnekte spesifik bir tarih ile iki tarih arası değer uygulama örneği bulunmaktadır. Bunların alabileceği değerlerin bir listesini şu sayfadan görebileceğiniz gibi, makro recorder ile denemeler sırasında da elde edebilirsiniz.

                    
                                    Sub pivotta_filtrekoy()
                                        'Tek fieldda tek değer filtreleme
                                        Sheets("Tarihsl Datanın Pivot ve Slcr").Select
                                        Application.EnableEvents = False 'ilgili sayfadaki eventler tetiklenmesin
                                        ActiveSheet.PivotTables("ptAy").ClearAllFilters

                                        ActiveSheet.PivotTables("ptAy").PivotFields("Ay").PivotFilters.Add2 _
                                            Type:=xlSpecificDate, Value1:="31.01.2016"
                                        ActiveSheet.PivotTables("ptAy").ClearAllFilters
                                        ActiveSheet.PivotTables("ptAy").PivotFields("Ay").PivotFilters.Add2 _
                                            Type:=xlDateBetween, Value1:="31.01.2016", Value2:="31.05.2016"
                                        Application.EnableEvents = True
                                    End Sub
                                        
                                        

Diğer PivotFilter örnekleri aşağıdaki gibi olabilir.

                    
                            ActiveCell.PivotField.PivotFilters.Add FilterType := xlThisWeek 
                            ActiveCell.PivotField.PivotFilters.Add FilterType := xlTopCount DataField := MyPivotField2 Value1 := 10 
                            ActiveCell.PivotField.PivotFilters.Add FilterType := xlCaptionIsNotBetween Value1 := "A" Value2 := "G" 
                            ActiveCell.PivotField.PivotFilters.Add FilterType := xlValueIsGreaterThanOrEqualTo DataField := MyPivotField2 Value1 := 10000 
                                
                                

1 fieldda 1 filtre uygulamanın alternatifi

1 fielda sadece 1 adet kriter gireceksek PivotFilter gayet uygun bir yöntemdir. Örnek olarak sadece "A" değerini filtrelemek için aşağıdaki kodu uygulayabilirsiniz.

                    
                                Sub pivotta_1_filtredene()
                                    'Tek fieldda tek değer filtreleme
                                    ActiveSheet.PivotTables("ptBolgekodUrun").PivotFields("Bölge Kodu").ClearAllFilters
                                    ActiveSheet.PivotTables("ptBolgekodUrun").PivotFields("Bölge Kodu").CurrentPage = "A"
                                End Sub
                                    
                                    

Dashboard yönetimi kısmında makroların gücünü döngüler ve koşullu yapıları kullanarak çok güzel görmüştük. Grafiklerde de benzer kolaylıklardan yararlanacağız. Tabiki PT'larda olduğu gibi grafik yaratmayla pek uğraşmayacağız. Otomasyon projelerinde kodunuzun bir grafik yaratması gerekse bile bunu recorder ile ürettiğiniz kodu elden geçirerek yapabilirsiniz.

Mesela yukarıda Slicerlar bölümünde 6 farklı renkli gösterilmiş dashboardu düşünün, orada o bloklar PT'lardan oluşuyordu, şimdi varsayalım ki bunlar birer grafik. Bu sefer her birininin tipini, boyutunu, pozisyonunu, lejandını, renkleri v.s tek seferde değiştirmek istiyoruz, tabiki bunu döngülerle yapacağız.

Veya grafiğe konu olan datasetinde seçilen bir değere göre gragiği dinamik olarak güncellemek gerekecek. Bu gibi işleri yine makro ile başaracağız.

Nesneler hiyerarşisi

Şimdi öncelikle elimizdeki nesneler bi bakalım

• Chart nesnesi: Bunlar bağımsız grafik sayfaları olabileceği gibi normal bir sayfa(worksheet) içindeki gömülü grafikler de olabilir. Ancak bunlardan sadece bağımsız sayfa olarak bulunanlar Charts koleksiyonunun bir üyesidir, gömülü olanlar değil.
• ChartObject nesnesi: Worksheet içinde bulunan grafiklerin(Worksheet Chartlarının) konteynerıdır. Esasen bir grafik nesnesi değil, onun kabuğudur. Propertylerine falan bakıldığında grafikten ziyade Shape nesnesinin özelliklerini görürsünüz. ChartObjects koleksiyonunun bir üyesidir. Aynı zamanda Shapes koleksiyonunun da bir üyesidir. Hatta macro recorder ile grafik oluşturduğunuzda Shapes üzerinden oluşturur.

Yani aslında 3 tür nesnemiz var diyebilir.

1. Worksheetlerdeki gömülü Chart: Chart. Parent nesnesi ChartObjecttir.
2. Bağımsız Chart: Bu da Chart'tır. Parent nesnesi Workbook'tur.
3. Worksheet Chartı için kontyner: ChartObject. Buna ulaşmadan içindeki Charta ulaşılamaz. Parent nesnesi Worksheet'tir.

Örnek birkaç erişim şekli şöyle olabilir:

                            
                    'Worksheet içindeki bir Chart'a zincirleme olarak
                    Sheets("Sheet1").ChartObjects("Chart 1").Chart.ChartTitle.Text = "Yeni başlık"
                    'ya da önce konteynerı seçince aktif olan ActiveChart ile
                    Sheets("Sheet1").ChartObjects("Chart 1").Activate
                    ActiveChart.ChartTitle.Text = "Yeni başlık"
                    'bağımsız chart
                    Sheets("Chart 1").ChartTitle.Text = "Yeni başlık" 'sayfa adından
                    ActiveWorkbook.Sheets("Chart1").ChartTitle.Text = "Yeni başlık" 'nesne adından
                            
                        

Bu bilgiler ışığında chartlarda dolaşma şu şekilde olur.

                            
                    Sub chartlarda_dolaşma()

                        Dim chto As ChartObject
                        Dim cht As Chart

                        'sayfa olan chartlarda dolaşalım
                        For Each cht In ActiveWorkbook.Charts
                            Debug.Print cht.Name, TypeName(cht), TypeName(cht.Parent)
                        Next cht

                        'gömülü chartlarda dolaşalım
                        For Each ws In ActiveWorkbook.Worksheets
                            For Each chto In ws.ChartObjects
                                Debug.Print chto.Name, chto.Index, chto.Parent.Name 'Chart'ın adı biraz anlamsız, ChartObject'in adını kullanalım
                            Next chto
                        Next ws

                    End Sub
                            
                        

Yaratım ve değişiklik

Yaratım ve özelliklerdeki değişiklikler için hep recorder kullanmanızı tavsiye ediyorum arkadaşlar. O yüzden buna ait kodları buraya koymuyorum.

Diğer hususlar

Grafik datasının olduğu bölgeyi grafikle kaplamak

Özellikle dashboard sayfalarında grafik datasının ortalıkta görünmesini istemeyiz. Gizli satır/kolon veya sayfanın aşağılarında bir yerlere koymak bir çözüm olabileceği gibi, data alanı çok küçük/büyük değilse bu bölgeyi grafiğin kendisiyle kapatmak bir çözüm olabilir.

Aşağıdaki kod ile bunu yapabiliriz. Kodda bir yardımcı fonksiyon kullanıyorum. Bu fonksiyonda F8 ile ilerleyerek "dizi" değişkenini incelerseniz adres1 ve adres2de ne yaptığımı anlayacaksınız.

Dashboard sayfanızdaki tüm grafiklerde döngüsel olarak çalışacak şekilde bu kodu modifiye edebilirsiniz.

Sub RangeiGrafikleKapla()

    Dim cht As ChartObject
    Dim grafikAlan As Range

    Set cht = ActiveChart.Parent
    Set grafikAlan = GrafikRange(cht.Chart)

    cht.Left = grafikAlan.Left
    cht.Width = grafikAlan.Width
    cht.Top = grafikAlan.Top
    cht.Height = grafikAlan.Height
End Sub	
'Yardımcı fonksiyonumuz
	Function GrafikRange(cht As Chart) As Range
		dizi = cht.SeriesCollection(1).Formula
		adres1 = Split(Replace(Split(dizi, ",")(1), cht.Parent.Parent.Name & "!", ""), ":")(0)
		adres2 = Split(Replace(Split(dizi, ",")(2), cht.Parent.Parent.Name & "!", ""), ":")(1)
		
		Set GrafikRange = Range(adres1, adres2)	
	End Function

Grafikleri silme ve gizleme

Silme ve gizleme işlemlerini Shapeler aracılığı ile yapabileceğimiz gibi ChartObject'in kendisiyle de yapabiliriz. Burada önemli olan Chart nesnesini değil ChartObject nesnesini silebildiğimizdir.

                    
                            ActiveChart.Delete 'çalışmaz
                            ActiveSheet.ChartObjects(1).Delete 'bu 1 nolu chartı siler
                            ActiveSheet.ChartObjects.Delete 'bu sayfadaki tüm grafikleri siler
                    
                

Chart sayfalarını ise normal sayfa siler gibi siliyoruz.